しろすけ技術研究所

#include <DFRobot_SD3031.h>
#include <Wire.h>

DFRobot_SD3031 rtc; 

const int P1 = D8;    //water charge pump
const int P2 = D2;    //water discharge pump
const int Air = D10;  //Aeration

#include <math.h>

#define TDS_PIN A1  //TDS
int TDS_sensor = 0;
float TDS_Voltage = 0;
float TDS = 0;

#include <OneWire.h>  // For Water Temp.
#include <DallasTemperature.h>
#define ONE_WIRE_BUS D3
#define SENSER_BIT 9  // 

OneWire oneWire(ONE_WIRE_BUS);
DallasTemperature sensors(&oneWire);


int LI1 = 0;  // UPPER_WaterLevel
int LI1_PIN = A0;

int LI2 = 0;  // LOWER_WaterLevel
const int LI2_PIN = D9;


volatile int8_t alarmFlag = 0;  //RTC alarm

unsigned long RTC_alarmTime;  // water discharge pump start time
unsigned long AjustStart;     // Ajust Concentration start time
unsigned long AjustTime;


#include <WiFi.h>  //wifi setting
const char SSID[] = "*******";
const char PASSWORD[] = "***********";


#include <Ambient.h>  //Ambient setting
unsigned int channelId = *****;
const char* writeKey = "***************";

WiFiClient client;
Ambient ambient;

#include <time.h>


void setup() {
  Serial.begin(115200);
  struct tm timeInfo;
  while (rtc.begin() != 0) {
    Serial.println("Failed to init chip, please check if the chip connection is fine. ");
    delay(1000);
  }

  pinMode(P1, OUTPUT);      //D8
  pinMode(P2, OUTPUT);      //D2
  pinMode(Air, OUTPUT);     //D10
  pinMode(TDS_PIN, INPUT);  //A1
  pinMode(LI1_PIN, INPUT);  //A0
  pinMode(LI2_PIN, INPUT);  //D9
                            //D4 --SDA for RTC
                            //D5 --SCL for RTC
                            //D6 --vacant
                            //D7 --INT from RTC
  pinMode(ONE_WIRE_BUS, INPUT);  //D3 --ONE WIRE BUS, DS18B20

  sensors.setResolution(SENSER_BIT);

  bool connecting = true;
  WiFi.begin(SSID, PASSWORD);
  while (connecting){
    Serial.print("WiFi connecting to the AP: ");
    Serial.println(SSID);
    unsigned long connect_start = millis();
    while (WiFi.status() != WL_CONNECTED && connect_start + 20000 > millis() ){
      Serial.print(".");
      delay(500);
    }
    if (WiFi.status() == WL_CONNECTED){
      connecting = false;
      delay(500);
    } else {
      Serial.println("retry");
      delay(500);
      esp_deep_sleep(500);
    }
  }

  configTzTime("JST-9", "ntp.nict.jp","ntp.jst.mfeed.ad.jp");
  getLocalTime(&timeInfo);
  rtc.setTime(timeInfo.tm_year +1900, timeInfo.tm_mon +1, timeInfo.tm_mday, timeInfo.tm_hour, timeInfo.tm_min, timeInfo.tm_sec);

  rtc.setAlarm(rtc.eSaturday, 10, 0, 0);  //Set weekly timed alarm
  attachInterrupt(digitalPinToInterrupt(D7), interrupt, FALLING);


  Serial.println("connected.");
  Serial.print("IP adress:");
  Serial.println(WiFi.localIP());

  ambient.begin(channelId, writeKey, &client);

}


void loop() {
  sTimeData_t sTime;  //now time
  sTime = rtc.getRTCTime();

  if (alarmFlag == 1) {
    LI2 = digitalRead(LI2_PIN);
    unsigned long P2_time = millis();
    digitalWrite(P2, HIGH);
    digitalWrite(P1, LOW);
    Serial.println("Water Discharge has been started.");
    unsigned long P2_work_time = P2_time - RTC_alarmTime;
    Serial.println(RTC_alarmTime, DEC);
    Serial.println(P2_time, DEC);
    Serial.println(P2_work_time, DEC);
    Serial.println(LI2);
    delay(1000);

    if (LI2 == 0 || P2_work_time >= 900000) {  //Limit setting for P2, water level or work time
      digitalWrite(P2, LOW);
      Serial.println("Water Discharge was finished.");
      rtc.clearAlarm();
      alarmFlag = 0;
      Serial.println("alarmFlag was cleared.");
      delay(1000);
    }
  } else {

    Serial.print(sTime.year, DEC);  //year
    Serial.print('/');
    Serial.print(sTime.month, DEC);  //month
    Serial.print('/');
    Serial.print(sTime.day, DEC);  //day
    Serial.print(" (");
    Serial.print(sTime.week);  //week
    Serial.print(") ");
    Serial.print(sTime.hour, DEC);  //hour
    Serial.print(':');
    Serial.print(sTime.minute, DEC);  //minute
    Serial.print(':');
    Serial.print(sTime.second, DEC);  //second
    Serial.println(' ');

    LI1 = analogRead(LI1_PIN);  //Check UPPER WaterLevel, Work P1 the Water Charge Pump
    if (LI1 >= 3500) {
      digitalWrite(P1, HIGH);
    } else {
      digitalWrite(P1, LOW);
    }

    Serial.print("UPPER Water Level = ");  //UPPER Water Level
    Serial.println(LI1, DEC);

    if (LI1 >= 3500) {
      ambient.set(1, 80);
    } else {
      (ambient.set(1, 100));
    }


    LI2 = digitalRead(LI2_PIN);  //Check LOWER WaterLevel

    Serial.print("LOWER Water Level = ");  //LOWER Water Level
    Serial.println(LI2, DEC);

    if (LI2 == 1) {
      ambient.set(8, 1);
    } else {
      (ambient.set(8, 0));
    }


    if ((sTime.hour >= 7) && (sTime.hour <= 17)) {  //aeration start ,stop time
      digitalWrite(Air, HIGH);
    } else {
      digitalWrite(Air, LOW);
    }


    float Water_Temp;  //Water Temp

    sensors.requestTemperatures();
    Water_Temp = sensors.getTempCByIndex(0);
    Serial.print("Water Temp = ");
    Serial.print(Water_Temp);
    Serial.println(" C");

    ambient.set(6, Water_Temp);


    float RTC_TEMP;  //RTC Temp
    RTC_TEMP = rtc.getTemperatureC();
    Serial.print("RTC Temp = ");
    Serial.print(RTC_TEMP);
    Serial.println(" C");

    ambient.set(4, RTC_TEMP);


    int P1_motion = digitalRead(P1);

      ambient.set(2, P1_motion);

    int Air_motion = digitalRead(Air);
    if (Air_motion == HIGH) {
      ambient.set(3, HIGH);
    } else if (Air_motion == LOW) {
      ambient.set(3, LOW);
    }

    TDS_sensor = analogRead(TDS_PIN);  //TDS
    TDS_Voltage = TDS_sensor * 5 / 4096.0;
    TDS = (133.42 * TDS_Voltage * TDS_Voltage * TDS_Voltage - 255.86 * TDS_Voltage * TDS_Voltage + 857.39 * TDS_Voltage) * 0.5;
    Serial.print("TDS = ");
    Serial.print(TDS);
    Serial.println(" ppm");
    Serial.println(" ");

    ambient.set(5, TDS);

    ambient.send();

    delay(1000);
  }
}

void interrupt(void) {
  alarmFlag = 1;
  RTC_alarmTime = millis();
}